home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Nibble Magazine
/
nib15.dsk
/
HEAD CLEANER.bas
< prev
next >
Wrap
BASIC Source File
|
2023-02-26
|
2KB
|
83 lines
10 REM **********************
11 REM * HEAD CLEANER *
12 REM * BY ART MENA *
13 REM * COPYRIGHT (C) 1983 *
14 REM * BY MICROSPARC, INC *
15 REM * LINCOLN, MA. 01773 *
16 REM **********************
100 REM
110 REM
120 REM USE THIS PROGRAM WITH
130 REM A DISK DRIVE HEAD
140 REM CLEANING KIT TO KEEP
150 REM YOUR DRIVES CLEAN.
160 REM
170 REM JUST ENTER "RUN" AND
180 REM FOLLOW THE DIRECTIONS.
190 REM
200 REM
210 B$ = CHR$(7) + CHR$(7) + CHR$(7)
220 GOSUB 820
230 REM GET THE DRIVE NUMBER
250 REM
260 TEXT : HOME : POKE -16368,0
270 VTAB 3: HTAB 12: INVERSE : PRINT " HEAD CLEANER ": NORMAL
280 PRINT : PRINT TAB( 13)"BY ART MENA"
290 PRINT CHR$(7)
300 PRINT : PRINT " ENTER THE DISK DRIVE NUMBER THAT"
310 PRINT "YOU WANT TO CLEAN (1/2,0=END) ?"
320 PRINT "===> ";: GET DR$
330 DR = VAL(DR$)
340 IF DR$ = "0" THEN TEXT : HOME : END
350 IF DR < >1 AND DR < >2 THEN PRINT : PRINT : FLASH : PRINT "INCORRECT DISK DRIVE";B$: NORMAL : FOR I = 1 TO 1000: NEXT I: GOTO 260
360 PRINT DR$: PRINT
370 REM
380 REM PRINT DIRECTIONS
390 REM
400 PRINT B$: PRINT " PUT SOME CLEANING FLUID ON A 5 1/4"
410 PRINT "INCH CLEANING DISKETTE AND PLACE IT"
420 PRINT "IN DRIVE NUMBER "DR$". PRESS ";: INVERSE : PRINT " RETURN ": NORMAL
430 PRINT "WHEN YOU ARE FINISHED."
440 REM
450 POKE -16368,0
460 IF PEEK( -16384) < >13 AND PEEK( -16384) < >141 THEN GOTO 460
470 POKE -16368,0
480 REM
490 POKE 818,DR
500 POKE 34,10: HOME
510 PRINT : PRINT CHR$(7)" RUNNING THE HEAD BACK AND FORTH"
520 PRINT " 4 TIMES. PRESS ";: INVERSE : PRINT " ESC ";: NORMAL : PRINT " TO STOP"
530 PRINT
540 REM
550 REM USE THE RWTS "SEEK"
560 REM COMMAND TO RUN
570 REM HEAD ACROSS THE DISK
580 REM
590 FOR CNT = 1 TO 4
600 VTAB 15: PRINT "COUNT ==> ";CNT
610 FOR TRACK = 0 TO 34
620 GOSUB 710
630 NEXT TRACK
640 FOR TRACK = 34 TO 1 STEP -1
650 GOSUB 710
660 NEXT TRACK
670 NEXT CNT
680 PRINT : PRINT "ALL DONE !"
690 FOR I = 1 TO 1500: NEXT I: GOTO 260
700 REM
710 REM HEAD SEEK SUBROUTINE
720 REM
730 IF PEEK( -16384) = 27 OR PEEK( -16384) = 155 THEN POP : GOTO 260
740 VTAB 17
750 PRINT "SEEKING TRACK ==> ";TRACK;" "
760 POKE 820,TRACK
770 CALL 837: REM CALL RWTS
780 RETURN
790 REM IOCB FOR RWTS
800 DATA 1,96,1,0,0,0,65,3,0,128,0,0,0,0,0,96
810 DATA 1,0,0,239,219,160,48,169,3,32,217,3,96
820 RESTORE
830 FOR I = 816 TO 844
840 READ D: POKE I,D
850 NEXT I
860 RETURN